This tutorial was created using ANSYS 7.0 The purpose of this tutorial is to outline the steps required to view cross sectional results (Deformation, Stress, etc.) of the following example.

ANSYS Command Listing

FINISH  
/CLEAR 

/Title, Cross-Sectional Results of a Simple Cantilever Beam
/PREP7

! All dims in mm
Width = 60
Height = 40
Length = 400

BLC4,0,0,Width,Height,Length	! Creates a rectangle

/ANGLE, 1 ,60.000000,YS,1 	! Rotates the display
/REPLOT,FAST			! Fast redisplay				

ET,1,SOLID45  			! Element type 
 
MP,EX,1,200000 			! Young's Modulus
MP,PRXY,1,0.3			! Poisson's ratio

esize,20			! Element size
vmesh,all			! Mesh the volume

FINISH  
/SOLU   			! Enter solution mode

ANTYPE,0			! Static analysis
ASEL,S,LOC,Z,0			! Area select at z=0
DA,All,ALL,0			! Constrain the area
ASEL,ALL			! Reselect all areas

KSEL,S,LOC,Z,Length		! Select certain keypoint
KSEL,R,LOC,Y,Height
KSEL,R,LOC,X,Width
FK,All,FY,-2500			! Force on keypoint
KSEL,ALL			! Reselect all keypoints

SOLVE				! Solve
FINISH  

/POST1 				! Enter post processor

PLNSOL,U,SUM,0,1		! Plot deflection
WPOFFS,Width/2,0,0      	! Offset the working plane for cross-section view
WPROTA,0,0,90			! Rotate working plane
/CPLANE,1               	! Cutting plane defined to use the WP
/TYPE,1,8               	! QSLICE display

WPCSYS,-1,0			! Deflines working plane location

WPOFFS,0,0,1/16*Length    	! Offset the working plane
/CPLANE,1                 	! Cutting plane defined to use the WP
/TYPE,1,5                 	! Use the capped hidden display
PLNSOL,S,EQV,0,1		! Plot equivalent stress

!Animation
ANCUT,43,0.1,5,0.05,0,0.1,7,14,2 ! Animate the slices