This tutorial was created using ANSYS 7.0 The purpose of this tutorial is to create and use 'paths' to provide extra detail during post processing. For example, one may want to determine the effects of stress concentrators along a certain path. Rather than plotting the entire contour plot, a plot of the stress along that path can be made.

In this tutorial, a steel plate measuring 100 mm X 200 mm X 10 mm will be used. Three holes are drilled through the vertical centerline of the plate. The plate is constrained in the y-direction at the bottom and a uniform, distributed load is pulling on the top of the plate.


ANSYS Command Listing

finish
/clear

/title, Defining Paths
/PREP7

! create geometry

BLC4,0,0,200,100
cyl4,50,50,10
cyl4,100,50,10
cyl4,150,50,10
asba,1,all

et,1,plane2,,,3		! Plane element
R,1,10			! thickness of plane
mp,ex,1,200000		! Young's Modulus
mp,prxy,1,0.3		! Poisson's ratio

esize,5 		! mesh size
amesh,all		! area mesh

finish
/solu

! apply constraints
lsel,s,loc,y,0		! select line for contraint application
dl,all,,UY              ! constrain all DOF's on this face
allsel

! apply loads
allsel			! restore entire selection
lsel,s,loc,y,100
SFL,all,PRES,-2000/10 	! apply a pressure load on a line
allsel

solve			! solve resulting system of equations
finish

! plot results
/window,1,top		! define a window (top half of screen)
/POST1
PLNSOL,S,eqv,2,1	! plot stress in xx direction (deformed and undeformed edge)
/window,1,off
/noerase

/window,2,bot		! define a window (bottom half of screen)
nsel,all		! define nodes to define path
nsel,s,loc,y,50		! choose nodes half way through structure
path,cutline,2,,1000	! define a path labeled cutline
ppath,1,,0,50		! define endpoint nodes on path
ppath,2,,200,50
PDEF,,S,eqv,AVG		! calculate equivalent stress on path
nsel,all
PLPAGM,SEQV,200,NODE	! show graph on plot with nodes