This tutorial was created using ANSYS 7.0 to solve a simple buckling problem.

It is recommended that you complete the NonLinear Tutorial prior to beginning this tutorial

Buckling loads are critical loads where certain types of structures become unstable. Each load has an associated buckled mode shape; this is the shape that the structure assumes in a buckled condition. There are two primary means to perform a buckling analysis:

  1. Eigenvalue

    Eigenvalue buckling analysis predicts the theoretical buckling strength of an ideal elastic structure. It computes the structural eigenvalues for the given system loading and constraints. This is known as classical Euler buckling analysis. Buckling loads for several configurations are readily available from tabulated solutions. However, in real-life, structural imperfections and nonlinearities prevent most real-world structures from reaching their eigenvalue predicted buckling strength; ie. it over-predicts the expected buckling loads. This method is not recommended for accurate, real-world buckling prediction analysis.

  2. Nonlinear

    Nonlinear buckling analysis is more accurate than eigenvalue analysis because it employs non-linear, large-deflection, static analysis to predict buckling loads. Its mode of operation is very simple: it gradually increases the applied load until a load level is found whereby the structure becomes unstable (ie. suddenly a very small increase in the load will cause very large deflections). The true non-linear nature of this analysis thus permits the modeling of geometric imperfections, load perterbations, material nonlinearities and gaps. For this type of analysis, note that small off-axis loads are necessary to initiate the desired buckling mode.

This tutorial will use a steel beam with a 10 mm X 10 mm cross section, rigidly constrained at the bottom. The required load to cause buckling, applied at the top-center of the beam, will be calculated.

ANSYS Command Listing

Eigenvalue Buckling
FINISH			! These two commands clear current data
/CLEAR

/TITLE,Eigenvalue Buckling Analysis

/PREP7			! Enter the preprocessor

ET,1,BEAM3		! Define the element of the beam to be buckled
R,1,100,833.333,10	! Real Consts: type 1, area (mm^2), I (mm^4), height (mm)
MP,EX,1,200000		! Young's modulus (in MPa)
MP,PRXY,1,0.3		! Poisson's ratio

K,1,0,0			! Define the geometry of beam (100 mm high)
K,2,0,100

L,1,2			! Draw the line

ESIZE,10		! Set element size to 1 mm
LMESH,ALL,ALL		! Mesh the line

FINISH
/SOLU			! Enter the solution mode

ANTYPE,STATIC		! Before you can do a buckling analysis, ANSYS
			! needs the info from a static analysis
PSTRES,ON		! Prestress can be accounted for - required
			! during buckling analysis
DK,1,ALL		! Constrain the bottom of beam

FK,2,FY,-1		! Load the top vertically with a unit load.
			! This is done so the eigenvalue calculated
			! will be the actual buckling load, since
			! all loads are scaled during the analysis.
SOLVE
FINISH

/SOLU			! Enter the solution mode again to solve buckling
ANTYPE,BUCKLE		! Buckling analysis
BUCOPT,LANB,1		! Buckling options - subspace, one mode
SOLVE
FINISH

/SOLU			! Re-enter solution mode to expand info - necessary
EXPASS,ON		! An expantion pass will be performed
MXPAND,1		! Specifies the number of modes to expand
SOLVE
FINISH

/POST1			! Enter post-processor
SET,LIST		! List eigenvalue solution - Time/Freq listing is the
			! force required for buckling (in N for this case).
SET,LAST		! Read in data for the desired mode
PLDISP			! Plots the deflected shape

NonLinear Buckling

FINISH			! These two commands clear current data
/CLEAR

/TITLE, Nonlinear Buckling Analysis
/PREP7			! Enter the preprocessor
ET,1,BEAM3		! Define element as beam3

MP,EX,1,200000		! Young's modulus (in Pa)
MP,PRXY,1,0.3		! Poisson's ratio

R,1,100,833.333,10	! area, I, height 

K,1,0,0,0		! Lower node
K,2,0,100,0		! Upper node (100 mm high)

L,1,2			! Draws line

ESIZE,1			! Sets element size to 1 mm
LMESH,ALL		! Mesh line

FINISH
/SOLU

ANTYPE,STATIC		! Static analysis (not buckling)
NLGEOM,ON		! Non-linear geometry solution supported
OUTRES,ALL,ALL		! Stores bunches of output
NSUBST,20		! Load broken into 5 load steps
NEQIT,1000		! Use 20 load steps to find solution
AUTOTS,ON		! Auto time stepping
LNSRCH,ON

/ESHAPE,1		! Plots the beam as a volume rather than line

DK,1,ALL,0		! Constrain bottom

FK,2,FY,-50000		! Apply load slightly greater than predicted
			! required buckling load to upper node
FK,2,FX,-250		! Add a horizontal load (0.5% FY) to initiate
			! buckling
SOLVE
FINISH

/POST26			! Time history post processor
RFORCE,2,1,F,Y		! Reads force data in variable 2
NSOL,3,2,U,Y		! Reads y-deflection data into var 3
XVAR,2			! Make variable 2 the x-axis
PLVAR,3			! Plots variable 3 on y-axis

/AXLAB,Y,DEFLECTION	! Changes y label
/AXLAB,X,LOAD		! Changes X label
/REPLOT