Suppose that the edge of a TV screen is given by 2x^4 + 3y^4 = 32.

If the intensity of radiation is given by I(x,y) = 1 / sqrt( x^2 + y^2 ),

find the maximum intensity on the edge of the TV screen.

PART I: GRAPHICAL EXPLORATION OF THE PROBLEM

We'll do some fancy plotting, so we need to tell Maple to load its fancy plotting commands ...

 > with( plots );

Define the intensity of radiation, and plot it ...

 > f := (x,y) -> 1 / sqrt( x^2 + y^2 );

 > plot3d( f(x,y), x=-3..3, y=-3..3, axes=BOXED );

Because of the symmetry in I(x,y), we expect the level curves to be circles in the (x,y) plane ...

Note that I'm using a two-step process here to see the plot.

First, I use the contourplot command, and assign the result to graph1

(note the use of the colon instead of the semicolon).

Then I use the display command to see the contourplot.

You don't have to do this.  You can use the contourplot directly (with a semicolon at the end instad of a colon).

The reason for using the two-step process  will become clear shortly.

 > graph1 := contourplot( f(x,y), x=-5..5, y=-5..5, contours=15, color=black ):

 > display( graph1 );

Indeed, we see circles, as expected.

Take a minute to interpret the level curves.

Which ones correspond to a low intensity,

and which ones correspond to a high intensity?

Now define the equation that determines the edge of the TV screen, and plot it ...

Note the use of the two-step process again.

 > g := (x,y) -> 2*x^4+3*y^4;

 > graph2 := implicitplot( g(x,y)=32, x=-3..3, y=-3..3, color=red, thickness=3 ):

 > display( graph2 );

Display the two graphs together

(now you see why the two-step process used above is helpful!),

Hint: think about the meaning of the contour plot.

Which of the level curves represent high intensity,

which represent lowest intensity?

 > display( graph1, graph2 );

The smallest  circle (why are we interested in this one?)

that just touches the edge of the screen does so at x=0.

On the edge of the tv screen (the red curve),

when x=0, y is given by the fourth root of 32/3 ...

 > root(32/3,4);

 > evalf(%);

By symmetry, maximum intensity is obtained at x=0, y=1.807204007 and at x=0, y=-1.807204007.

At those points, what is the intensity?

 > f( 0, root(32/3,4) );

 > evalf(%);

PART II: SAME PROBLEM, NOW SOLVED WITH THE TECHNIQUE OF LAGRANGE MULTIPLIERS

We are looking for locations where the gradient of f and the gradient of g are parallel to each other.  If we let lam be the parallellity parameter, then we need to solve: grad(f) = lam*grad(g) together with the constraint that the solution must lie on the curve g(x,y)=32.  This gives three equations for three unknowns, as follows:

 > dfdx := diff( f(x,y), x ):

 > dfdy := diff( f(x,y), y ):

 > dgdx := diff( g(x,y), x ):

 > dgdy := diff( g(x,y), y ):

 > solve( {dfdx=lam*dgdx, dfdy=lam*dgdy, g(x,y)=32}, {x,y,lam} );

Mmh, we're not getting a solution.

Maple is having trouble solving this system of equations analytically/symbolically.

Try helping Maple along a bit, and look for numerical solutions

(by symmetry, there must be two points) ...

 > fsolve( {dfdx=lam*dgdx, dfdy=lam*dgdy, g(x,y)=32}, {x,y,lam}, y=-2..-1.5 );

 > fsolve( {dfdx=lam*dgdx, dfdy=lam*dgdy, g(x,y)=32}, {x,y,lam}, y=1.5..2 );

We found exactly the same points as above.

Use the same method to find the locations where the radiation is minimized ...

 > fsolve( {dfdx=lam*dgdx, dfdy=lam*dgdy, g(x,y)=32}, {x,y,lam}, x=-2.5..-1.5);

Check the value of the radiation at this point ...

 > f(-1.760223474,-1.437216448);

Exercise: I have found one of the minima.

Find the others (how many?).