abstract class LineGraphData {
  abstract float getMinDomain();
  abstract float getMaxDomain();
  abstract float getMinRange();
  abstract float getMaxRange();
  abstract int getNumData();
  abstract void reset();
  abstract float[] getNextData();
  abstract color getColor();
  abstract String getLabel();
}

class LineGraph {
  LineGraphData[] data=null;
  int x, y, w, h;
  PFont font;
  int fontSize;
  String title=null;
  String xLabel=null;
  String yLabel=null;
  float xMin, xMax, yMin, yMax;
  float xMinX, xMaxX, yMinY, yMaxY;

  NumberFormat numFormat;
  
  LineGraph(PFont font, int fontSize, String title, String xLabel, String yLabel) {
    this.x = x;
    this.y = y;
    this.w = w;
    this.h = h;
    this.font = font;
    this.fontSize = fontSize;
    this.title = title;
    this.xLabel = xLabel;
    this.yLabel = yLabel;
    
    numFormat = new DecimalFormat("0.00");
  }
  
  void addGraphData(LineGraphData gd) {
    LineGraphData[] newData;
    float xMinG, xMaxG, yMinG, yMaxG;
    int numData;
    
    if (gd == null) return;
    
    xMinG = gd.getMinDomain();
    xMaxG = gd.getMaxDomain();
    yMinG = gd.getMinRange();
    yMaxG = gd.getMaxRange();
    
    if (data==null) {
      newData = new LineGraphData[1];
      numData = 0;
      xMin = xMinG;
      xMax = xMaxG;
      yMin = yMinG;
      yMax = yMaxG;
    }
    else {
      numData = data.length;
      newData = new LineGraphData[numData+1];
      xMin = min(xMin, xMinG);
      xMax = max(xMax, xMaxG);
      yMin = min(yMin, yMinG);
      yMax = max(yMax, yMaxG);
    }
    for (int i=0; i<numData; ++i) {
      newData[i] = data[i];
    }
    newData[numData] = gd;
    data = newData;
  }
  
  void draw(PGraphics out, float x, float y, float w, float h) {
    String xMinStr, xMaxStr, yMinStr, yMaxStr;
    float  xMinW, xMaxW, yMinW, yMaxW;
    float xLeft, xRight, yTop, yBottom;
    int pad = 10;
    
    out.textFont(font, fontSize);
    out.textMode(SCREEN);
    xMinStr = numFormat.format(xMin);
    xMaxStr = numFormat.format(xMax);
    yMinStr = numFormat.format(yMin);
    yMaxStr = numFormat.format(yMax);
    xMinW = out.textWidth(xMinStr);
    xMaxW = out.textWidth(xMaxStr);
    yMinW = out.textWidth(yMinStr);
    yMaxW = out.textWidth(yMaxStr);
    yTop = y;
    yBottom = y+h - 2*(fontSize + 3);

    xLeft = max(yMinW, yMaxW);
    if (yLabel != null) {
      xLeft = max(xLeft, out.textWidth(yLabel));
    }
    xLeft += (x+3);
    xRight = x + w;

    out.fill(255);
    out.stroke(255);
    if (title != null) {
      yTop += fontSize + 3;
      out.textAlign(CENTER, BOTTOM);
      out.text(title, (xRight + xLeft) / 2.0, yTop);
    }
    out.triangle(xLeft, yTop, xLeft-5, yTop+5, xLeft+5, yTop+5);
    yTop += 5;
    out.triangle(xRight, yBottom, xRight-5, yBottom+5, xRight-5, yBottom-5);
    xRight -= 5;
    out.line(xLeft, yBottom, xLeft, yTop);
    out.line(xLeft, yBottom, xRight, yBottom);
    yTop += 5;
    xRight -= 5;
    out.textAlign(RIGHT, CENTER);
    out.text(yLabel, xLeft - 10, (yTop+yBottom)/2.0);
    out.textAlign(CENTER, TOP);
    out.text(xLabel, (xLeft + xRight) / 2.0, yBottom + 6);
    
    xMinX = xLeft + pad;
    xMaxX = xRight - pad;
    yMaxY = yTop + pad;
    yMinY = yBottom - pad;
    
    //out.fill(0);
    //out.rectMode(CORNER);
    //out.rect(x,y,w,h);
    out.fill(153);
    out.stroke(153);
    out.line(xLeft - 2, yMinY, xRight, yMinY);
    out.line(xLeft - 2, yMaxY, xRight, yMaxY);
    out.line(xMinX, yBottom+2, xMinX, yTop);
    out.line(xMaxX, yBottom+2, xMaxX, yTop);
    out.textAlign(RIGHT, CENTER);
    out.text(yMinStr, xLeft - 4, yMinY);
    out.text(yMaxStr, xLeft - 4, yMaxY);
    out.textAlign(LEFT, TOP);
    out.text(xMinStr, xMinX, yBottom + 4);
    out.textAlign(RIGHT, TOP);
    out.text(xMaxStr, xMaxX, yBottom + 4);

    float[] labelWidths = new float[data.length];
    float labelSum = 0, labelSpacing = 0, labelStart;
    int numLabels = 0;
    for(int j=0;j<data.length;++j) {
      data[j].reset();
      float[] last = data[j].getNextData();
      last[0] = getScreenX(last[0]);
      last[1] = getScreenY(last[1]);
      
      out.stroke(data[j].getColor());
      for (int i=1; i < data[j].getNumData(); ++i) {
        float[] p = data[j].getNextData();
        p[0] = getScreenX(p[0]);
        p[1] = getScreenY(p[1]);
        out.line(last[0], last[1], p[0], p[1]);
        last = p;
      }
      String label = data[j].getLabel();
      if (label != null) {
        labelWidths[j] = out.textWidth(label);
        labelSum += labelWidths[j];
        ++numLabels;
      }
    }
    if (numLabels > 1) {
      labelSpacing = (xRight - xLeft - labelSum) / (numLabels - 1.0);
    }
    labelStart = xLeft;
    out.textAlign(LEFT, BOTTOM);
    for (int j=0; j < data.length; ++j) {
      String label = data[j].getLabel();
      if (label != null) {
        out.fill(data[j].getColor());
        out.text(label, labelStart, yBottom + 2*fontSize+8);
        labelStart+=labelSpacing+out.textWidth(label);
      }
    }
  }
  
  float getScreenX(float in) {
    return xMinX + (xMaxX - xMinX) * (in - xMin) / (xMax - xMin);
  }
  float getScreenY(float in) {
    return yMinY + (yMaxY - yMinY) * (in - yMin) / (yMax - yMin);
  }

}