/* Copyright (c) 2010, Chris Want 
   Please see BSD style licence at the end of this file */

class Iso3dPanel extends GraphicsPlacementElement {
  DataModel    data;
  ControlModel control;
  PGraphics   p2d;
  PImage      glowData=null;
  PImage      glowClicked=null;
  float[]     xData, yData;
  float  xClicked, yClicked;
  PFont       font;
  float[]     north;
  Scene scene=null;
  
  Iso3dPanel(DataModel data, ControlModel control, PFont font, float x, float y, float w, float h) {
    super(x, y, w, h, P3D);
    
    this.data    = data;
    this.control = control;
    this.font = font;
    
    glowData=loadImage("glow.png");
    glowClicked=loadImage("yellow-glow.png");

    p2d = createGraphics(round(w), round(h), P2D);

    scene = new Scene();
    scene.setViewCenter(data.krig.out, (PGraphics) pi);
    scene.zUpOn();
  }

  void draw(PGraphics out) {
    draw(out, data.krig.out, scene);
  }
  
  void draw(PGraphics out, ScalarField sc, Scene scene) {
    boolean modified=false;
    
    int i;
    scene.doRotation();
  
    //if (scene.getUpdateView()) {
    if (redraw) {
      pi.beginDraw();
    
      scene.drawBackground(pi, 255);

      scene.transformView(pi);

      drawOutline(sc, pi);
      getDataScreenCoords(pi, control.clickedData);
      getClickedScreenCoords(pi);
      getNorth(pi, sc);
      for (i =0; i < data.numSurf; ++i) {
        data.surfaces[i].render(pi);
      }
      if (data.invalidSurface != null) {
        data.invalidSurface.render(pi);
      }
      
      scene.restoreView(pi);

      pi.endDraw();

      scene.setUpdateView(false);
      modified=true;
    }
    if (modified) {
      // Draw 2d elements
      p2d.beginDraw();
      p2d.image(pi, 0, 0);
      p2d.endDraw();
      drawDataPoints(scene, p2d, 0.1, control.clickedData);
      drawClicked(scene, p2d, 0.1);
      drawLambdas(scene, p2d);
      drawNorth(p2d);
      p2d.noFill();
      p2d.stroke(204, 204, 204);
      p2d.rect(0, 0, w-1, h-1);

      out.image(p2d, x, y);
      
    }


  }
  
  void mouseMoved() {
    // check GUI elements for rollover
    if (mouseOver()) scene.mouseMoved();
  }

  void mousePressed() {
    if (mouseOver()) scene.mousePressed();
  }

  void mouseReleased() {
    scene.mouseReleased();
  }

  void drawOutline(ScalarField scalars, PGraphics pg) {
    float layer;
    int a;
  
    if (scalars == null) return;
  
    pg.stroke(color(102, 102, 102));
    pg.beginShape(LINES);
    pg.vertex(scalars.xMin, scalars.yMin, scalars.zMin);
    pg.vertex(scalars.xMax, scalars.yMin, scalars.zMin);
    pg.vertex(scalars.xMin, scalars.yMax, scalars.zMin);
    pg.vertex(scalars.xMax, scalars.yMax, scalars.zMin);
    pg.vertex(scalars.xMin, scalars.yMin, scalars.zMin);
    pg.vertex(scalars.xMin, scalars.yMax, scalars.zMin);
    pg.vertex(scalars.xMax, scalars.yMin, scalars.zMin);
    pg.vertex(scalars.xMax, scalars.yMax, scalars.zMin);

    if (scalars.zRes > 1 ) {
      pg.vertex(scalars.xMin, scalars.yMin, scalars.zMax);
      pg.vertex(scalars.xMax, scalars.yMin, scalars.zMax);
      pg.vertex(scalars.xMin, scalars.yMax, scalars.zMax);
      pg.vertex(scalars.xMax, scalars.yMax, scalars.zMax);
      pg.vertex(scalars.xMin, scalars.yMin, scalars.zMax);
      pg.vertex(scalars.xMin, scalars.yMax, scalars.zMax);
      pg.vertex(scalars.xMax, scalars.yMin, scalars.zMax);
      pg.vertex(scalars.xMax, scalars.yMax, scalars.zMax);

      pg.vertex(scalars.xMin, scalars.yMin, scalars.zMin);
      pg.vertex(scalars.xMin, scalars.yMin, scalars.zMax);
      pg.vertex(scalars.xMin, scalars.yMax, scalars.zMin);
      pg.vertex(scalars.xMin, scalars.yMax, scalars.zMax);
      pg.vertex(scalars.xMax, scalars.yMin, scalars.zMin);
      pg.vertex(scalars.xMax, scalars.yMin, scalars.zMax);
      pg.vertex(scalars.xMax, scalars.yMax, scalars.zMin);
      pg.vertex(scalars.xMax, scalars.yMax, scalars.zMax);
    }
    pg.endShape();

    if (scalars.zRes == 1) {
      layer = scalars.zMin;
    }
    else {
      layer = scalars.zMin + control.xylayer * (scalars.zMax - scalars.zMin) / (scalars.zRes - 1);
    }
    if ( control.probeOverXY() ) {
      a = 255;
    }
    else {
      a=153;
    }
    pg.stroke(color(204, 204, 153, a));
    pg.beginShape(LINES);
    pg.vertex(scalars.xMin, scalars.yMin, layer);
    pg.vertex(scalars.xMin, scalars.yMax, layer);
    pg.vertex(scalars.xMax, scalars.yMin, layer);
    pg.vertex(scalars.xMax, scalars.yMax, layer);
    pg.vertex(scalars.xMin, scalars.yMin, layer);
    pg.vertex(scalars.xMax, scalars.yMin, layer);
    pg.vertex(scalars.xMin, scalars.yMax, layer);
    pg.vertex(scalars.xMax, scalars.yMax, layer);
    pg.endShape();
    if ( a==255 ) {
      pg.beginShape(LINES);
      pg.vertex(control.probe[0], scalars.yMin, layer);
      pg.vertex(control.probe[0], scalars.yMax, layer);
      pg.vertex(scalars.xMin, control.probe[1], layer);
      pg.vertex(scalars.xMax, control.probe[1], layer);
      pg.endShape();
    }

    if (scalars.zRes == 1) return;

      layer = scalars.xMin + control.yzlayer * (scalars.xMax - scalars.xMin) / (scalars.xRes - 1);
    if ( control.probeOverYZ() ) {
      a = 255;
    }
    else {
      a=153;
    }
    pg.stroke(color(204, 153, 204, a));
    pg.beginShape(LINES);
    pg.vertex(layer, scalars.yMin, scalars.zMin);
    pg.vertex(layer, scalars.yMin, scalars.zMax);
    pg.vertex(layer, scalars.yMax, scalars.zMin);
    pg.vertex(layer, scalars.yMax, scalars.zMax);
    pg.vertex(layer, scalars.yMin, scalars.zMin);
    pg.vertex(layer, scalars.yMax, scalars.zMin);
    pg.vertex(layer, scalars.yMin, scalars.zMax);
    pg.vertex(layer, scalars.yMax, scalars.zMax);
    pg.endShape();
    if ( a==255 ) {
      pg.beginShape(LINES);
      pg.vertex(layer, control.probe[1], scalars.zMin);
      pg.vertex(layer, control.probe[1], scalars.zMax);
      pg.vertex(layer, scalars.yMin, control.probe[2]);
      pg.vertex(layer, scalars.yMax, control.probe[2]);
      pg.endShape();
    }

    layer = scalars.yMin + control.xzlayer * (scalars.yMax - scalars.yMin) / (scalars.yRes - 1);
    if ( control.probeOverXZ() ) {
      a = 255;
    }
    else {
      a=153;
    }
    pg.stroke(color(153, 204, 204, a));
    pg.beginShape(LINES);
    pg.vertex(scalars.xMin, layer, scalars.zMin);
    pg.vertex(scalars.xMin, layer, scalars.zMax);
    pg.vertex(scalars.xMax, layer, scalars.zMin);
    pg.vertex(scalars.xMax, layer, scalars.zMax);
    pg.vertex(scalars.xMin, layer, scalars.zMin);
    pg.vertex(scalars.xMax, layer, scalars.zMin);
    pg.vertex(scalars.xMin, layer, scalars.zMax);
    pg.vertex(scalars.xMax, layer, scalars.zMax);
    pg.endShape();
    if ( a==255 ) {
      pg.beginShape(LINES);
      pg.vertex(control.probe[0], layer, scalars.zMin);
      pg.vertex(control.probe[0], layer, scalars.zMax);
      pg.vertex(scalars.xMin, layer, control.probe[2]);
      pg.vertex(scalars.xMax, layer, control.probe[2]);
      pg.endShape();
    }

  }
  
  void getDataScreenCoords(PGraphics pg, KrigData dat) {
    if (dat == null) return;
    if (dat.ndata > 0) {
      xData = new float[dat.ndata];
      yData = new float[dat.ndata];
      for (int i = 0; i < dat.ndata; ++i) {
        xData[i] = pg.screenX(dat.x[i], dat.y[i], dat.z[i]);
        yData[i] = pg.screenY(dat.x[i], dat.y[i], dat.z[i]);
      }
    }
  }
  
  void getClickedScreenCoords(PGraphics pg) {
    if (control.clicked != null) {
      xClicked = pg.screenX(control.clicked[0],control.clicked[1], control.clicked[2]);
      yClicked = pg.screenY(control.clicked[0],control.clicked[1], control.clicked[2]);
    }
  }
  
  void getNorth(PGraphics pg, ScalarField sc) {
    float ox, oy, px, py, dx, dy, len;
    float midX, midY, midZ;
    midX = (sc.xMin + sc.xMax) / 2.0;
    midY = (sc.yMin + sc.yMax) / 2.0;
    if (sc.zRes == 1) {
      midZ = sc.zMin;
    }
    else {
      midZ = (sc.zMin + sc.zMax) / 2.0;
    }
    
    ox = pg.screenX(midX, midY, midZ);
    oy = pg.screenY(midX, midY, midZ);
    px = pg.screenX(midX, sc.yMax, midZ);
    py = pg.screenY(midX, sc.yMax, midZ);
    dx = px - ox;
    dy = py - oy;
    len = sqrt(dx*dx + dy*dy);
    if (len > 0.0001) {
      north = new float[] { dx/len, dy/len };
    }
    else {
      north = null;
    }
  }

  void drawDataPoints(Scene scene, float hotScale, float[] x, float[] y, float[] z, KrigData dat) {
    drawDataPoints(scene, g, hotScale, dat);
  }

  void drawDataPoints(Scene scene, PGraphics pg, float hotScale, KrigData dat) {
    if (control.clicked == null) return;
    if (dat == null) return;
    if (dat.ndata > 0) {
      pg.noStroke();
      pg.textureMode(NORMALIZED);
      for (int i = 0; i < dat.ndata; ++i) {
        float currScale = scene.getScale();
        pg.image(glowData, xData[i]-currScale*hotScale, yData[i]-currScale*hotScale,
                 2*currScale*hotScale, 2*currScale*hotScale);
      }
    }
  }

  void drawClicked(Scene scene, PGraphics pg,  float hotScale) {
    if (control.clicked != null) {
      pg.noStroke();
      pg.textureMode(NORMALIZED);
      float currScale = scene.getScale();
      pg.image(glowClicked, xClicked-currScale*hotScale, yClicked-currScale*hotScale,
               2*currScale*hotScale, 2*currScale*hotScale);
    }
  }


  void drawLambdas(Scene scene, PGraphics pg) {
    float[] lambda;
    if (control.clicked != null) {
      if (control.clickedData != null) {
        pg.textFont(font,12);
        pg.textMode(SCREEN);
        pg.fill(255, 255, 255);
        lambda = data.getLambda();
        pg.textAlign(LEFT);
        for (int i = 0; i < control.clickedData.ndata; ++i) {
          pg.text(lambda[i], xData[i], yData[i]);
        }
      }
    }
  }
  
  void drawNorth(PGraphics pg) {
    float radius = 10;
    float x1 = getX(20+radius), y1 = getY(h-(20+radius));
    //pg.smooth();
    pg.fill(0, 102);
    pg.stroke(255, 102);
    pg.ellipseMode(RADIUS);
    pg.ellipse(x1, y1, radius, radius);
    if (north != null) {
      pg.line(x1, y1, x1+radius*north[0], y1+radius*north[1]);
      pg.textFont(font,12);
      pg.textMode(SCREEN);
      pg.textAlign(CENTER, CENTER);
      pg.fill(255, 102);
      pg.text("N", x1+(radius+8)*north[0], y1+(radius+8)*north[1]);
    }
    pg.noSmooth();
  }
  
  void updateState() {
    scene.setViewCenter(data.krig.out, (PGraphics) pi);
  }
}

/* Copyright (c) 2010, Chris Want, Research Support Group,
   AICT, University of Alberta. All rights reserved.

  Redistribution and use in source and binary forms, with or without 
  modification, are permitted provided that the following conditions are met:

  1) Redistributions of source code must retain the above copyright 
     notice, this list of conditions and the following disclaimer.
  2) Redistributions in binary form must reproduce the above copyright 
     notice, this list of conditions and the following disclaimer in the 
     documentation and/or other materials provided with the distribution.

  THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" 
  AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE 
  IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE 
  ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT OWNER OR CONTRIBUTORS BE 
  LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR 
  CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF  
  SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS 
  INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN 
  CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) 
  ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF 
  THE POSSIBILITY OF SUCH DAMAGE.

  Contributors: Chris Want (University of Alberta)
*/